Function: bug-reference-push-button

bug-reference-push-button is an interactive and byte-compiled function defined in bug-reference.el.gz.

Signature

(bug-reference-push-button &optional POS USE-MOUSE-ACTION)

Documentation

Open URL corresponding to the bug reference at POS.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/bug-reference.el.gz
;; Taken from button.el.
(defun bug-reference-push-button (&optional pos _use-mouse-action)
  "Open URL corresponding to the bug reference at POS."
  (interactive
   (list (if (integerp last-command-event) (point) last-command-event)))
  (when (null bug-reference-url-format)
    (user-error
     "You must customize some bug-reference variables; see Emacs info node Bug Reference"))
  (if (and (not (integerp pos)) (eventp pos))
      ;; POS is a mouse event; switch to the proper window/buffer
      (let ((posn (event-start pos)))
        (with-current-buffer (window-buffer (posn-window posn))
          (bug-reference-push-button (posn-point posn) t)))
    ;; POS is just normal position.
    (dolist (o (overlays-at pos))
      ;; It should only be possible to have one URL overlay.
      (let ((url (overlay-get o 'bug-reference-url)))
        (when url
          (browse-url url))))))