Function: calc-edit-macro-combine-alg-ent

calc-edit-macro-combine-alg-ent is a byte-compiled function defined in calc-prog.el.gz.

Signature

(calc-edit-macro-combine-alg-ent)

Documentation

Put an entire algebraic entry on a single line.

Source Code

;; Defined in /usr/src/emacs/lisp/calc/calc-prog.el.gz
(defun calc-edit-macro-combine-alg-ent ()
  "Put an entire algebraic entry on a single line."
  (let ((line (calc-edit-macro-command))
        (type (calc-edit-macro-command-type))
        curline
        match)
    (goto-char (line-beginning-position))
    (kill-line 1)
    (setq curline (calc-edit-macro-command))
    (while (and curline
                (not (string-equal "RET" curline))
                (not (setq match (string-match "<return>" curline))))
      (setq line (concat line curline))
      (kill-line 1)
      (setq curline (calc-edit-macro-command)))
    (when match
      (kill-line 1)
      (setq line (concat line (substring curline 0 match))))
    (setq line (string-replace "SPC" " SPC "
                               (string-replace " " "" line)))
    (insert line "\t\t\t")
    (if (> (current-column) 24)
        (delete-char -1))
    (insert ";; " type "\n")
    (if match
        (insert "RET\t\t\t;; calc-enter\n"))))