Function: calc-mode-var-list-restore-saved-values

calc-mode-var-list-restore-saved-values is a byte-compiled function defined in calc.el.gz.

Signature

(calc-mode-var-list-restore-saved-values)

Documentation

Restore the user-saved values of the variables in calc-mode-var-list.

Source Code

;; Defined in /usr/src/emacs/lisp/calc/calc.el.gz
(defun calc-mode-var-list-restore-saved-values ()
  "Restore the user-saved values of the variables in `calc-mode-var-list'."
  (let ((newvarlist '()))
    (save-excursion
      (let (pos
            (file (substitute-in-file-name calc-settings-file)))
        (when (and
               (file-regular-p file)
               (set-buffer (find-file-noselect file))
               (goto-char (point-min))
               (search-forward ";;; Mode settings stored by Calc" nil t)
               (progn
                 (forward-line 1)
                 (setq pos (point))
                 (search-forward "\n;;; End of mode settings" nil t)))
          (beginning-of-line)
          (calc-mode-var-list-restore-default-values)
          (eval-region pos (point))
          (let ((varlist calc-mode-var-list))
            (while varlist
              (let ((var (car varlist)))
                (setq newvarlist
                      (cons (list (car var) (symbol-value (car var)))
                            newvarlist)))
              (setq varlist (cdr varlist)))))))
    (if newvarlist
        (mapcar (lambda (v) (set (car v) (nth 1 v)))
                newvarlist)
      (calc-mode-var-list-restore-default-values))))