Function: calculator-rotate-displayer

calculator-rotate-displayer is an interactive and byte-compiled function defined in calculator.el.gz.

Signature

(calculator-rotate-displayer &optional NEW-DISP)

Documentation

Switch to the next displayer on the calculator-displayers list.

Can be called with an optional argument NEW-DISP to force rotation to that argument. If radix output mode is active, toggle digit grouping.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/calculator.el.gz
(defun calculator-rotate-displayer (&optional new-disp)
  "Switch to the next displayer on the `calculator-displayers' list.
Can be called with an optional argument NEW-DISP to force rotation to
that argument.
If radix output mode is active, toggle digit grouping."
  (interactive)
  (cond
    (calculator-output-radix
     (setq calculator-radix-grouping-mode
           (not calculator-radix-grouping-mode))
     (calculator-message
      "Digit grouping mode %s."
      (if calculator-radix-grouping-mode "ON" "OFF")))
    (t
     (setq calculator-displayers
           (if (and new-disp (memq new-disp calculator-displayers))
             (let ((tmp nil))
               (while (not (eq (car calculator-displayers) new-disp))
                 (push (pop calculator-displayers) tmp))
               (setq calculator-displayers
                     (nconc calculator-displayers (nreverse tmp))))
             (nconc (cdr calculator-displayers)
                    (list (car calculator-displayers)))))
     (calculator-message
      "Using %s." (cadr (car calculator-displayers)))))
  (calculator-enter))