Function: checkdoc-message-text-next-string

checkdoc-message-text-next-string is a byte-compiled function defined in checkdoc.el.gz.

Signature

(checkdoc-message-text-next-string END)

Documentation

Move cursor to the next checkable message string after point.

Return the message classification. Argument END is the maximum bounds to search in.

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/checkdoc.el.gz
(defun checkdoc-message-text-next-string (end)
  "Move cursor to the next checkable message string after point.
Return the message classification.
Argument END is the maximum bounds to search in."
  (let ((return nil))
    (while (and (not return)
                (re-search-forward
                 (rx "("
                     (* (syntax whitespace))
                     (group
                      (or (seq (* (group (or wordchar (syntax symbol))))
                               "error")
                          (seq (* (group (or wordchar (syntax symbol))))
                               (or "y-or-n-p" "yes-or-no-p")
                               (? (group "-with-timeout")))
                          "checkdoc-autofix-ask-replace"))
                     (+ (any "\n\t ")))
                 end t))
      (let* ((fn (match-string 1))
	     (type (cond ((string-match "error" fn)
			  'error)
			 (t 'y-or-n-p))))
	(if (string-match "checkdoc-autofix-ask-replace" fn)
	    (progn (forward-sexp 2)
		   (skip-chars-forward " \t\n")))
	(if (and (eq type 'y-or-n-p)
                 (looking-at (rx "(format" (? "-message") (+ (any " \t\n")))))
	    (goto-char (match-end 0)))
	(skip-chars-forward " \t\n")
	(if (not (looking-at "\""))
	    nil
	  (setq return type))))
    return))