Function: cider-apropos-select

cider-apropos-select is an autoloaded, interactive and byte-compiled function defined in cider-apropos.el.

Signature

(cider-apropos-select QUERY &optional NS DOCS-P PRIVATES-P CASE-SENSITIVE-P)

Documentation

Similar to cider-apropos, but presents the results in a completing read.

Show all symbols whose names match QUERY, a regular expression. QUERY can also be a list of space-separated words (e.g. take while) which will be converted to a regular expression (like take.+while) automatically behind the scenes. The search may be limited to the namespace NS, and may optionally search doc strings (based on DOCS-P), include private vars
(based on PRIVATES-P), and be case-sensitive (based on CASE-SENSITIVE-P).

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260414.1619/cider-apropos.el
;;;###autoload
(defun cider-apropos-select (query &optional ns docs-p privates-p case-sensitive-p)
  "Similar to `cider-apropos', but presents the results in a completing read.
Show all symbols whose names match QUERY, a regular expression.
QUERY can also be a list of space-separated words (e.g. take while) which
will be converted to a regular expression (like take.+while) automatically
behind the scenes.  The search may be limited to the namespace NS, and may
optionally search doc strings (based on DOCS-P), include private vars
\(based on PRIVATES-P), and be case-sensitive (based on CASE-SENSITIVE-P)."
  (interactive
   (cons (read-string "Search for Clojure symbol (a regular expression): ")
         (when current-prefix-arg
           (list (let ((ns (completing-read "Namespace (default is all): " (cider-sync-request:ns-list))))
                   (if (string= ns "") nil ns))
                 (y-or-n-p "Search doc strings? ")
                 (y-or-n-p "Include private symbols? ")
                 (y-or-n-p "Case-sensitive? ")))))
  (cider-ensure-connected)
  (cider-ensure-op-supported "apropos")
  (if-let* ((summary (cider-apropos-summary
                      query ns docs-p privates-p case-sensitive-p))
            (results (mapcar (lambda (r) (nrepl-dict-get r "name"))
                             (cider-sync-request:apropos query ns docs-p privates-p case-sensitive-p))))
      (cider-apropos-act-on-symbol (completing-read (concat summary ": ") results))
    (message "No apropos matches for %S" query)))