Function: cider-browse-ns--render-items

cider-browse-ns--render-items is a byte-compiled function defined in cider-browse-ns.el.

Signature

(cider-browse-ns--render-items ITEMS)

Documentation

Render the nrepl-dict ITEMS to the browse-ns buffer.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260414.1619/cider-browse-ns.el
(defun cider-browse-ns--render-items (items)
  "Render the nrepl-dict ITEMS to the browse-ns buffer."
  (let* ((max-length (cider-browse-ns--column-width items)))
    (cl-flet
        ((keys-from-pred
          (pred items)
          (nrepl-dict-keys (nrepl-dict-filter (lambda (_ var-meta)
                                                (funcall pred var-meta))
                                              items))))
      (cond
       ((eql cider-browse-ns-group-by 'type)
        (let* ((func-keys (keys-from-pred #'cider-browse-ns--meta-function-p items))
               (macro-keys (keys-from-pred #'cider-browse-ns--meta-macro-p items))
               (var-keys (keys-from-pred #'cider-browse-ns--meta-var-p items))
               (test-keys (keys-from-pred #'cider-browse-ns--meta-test-p items)))
          (cider-browse-ns--display-list func-keys items max-length "Functions")
          (cider-browse-ns--display-list macro-keys items max-length "Macros")
          (cider-browse-ns--display-list var-keys items max-length "Vars")
          (cider-browse-ns--display-list test-keys items max-length "Tests")))
       ((eql cider-browse-ns-group-by 'visibility)
        (let* ((public-keys
                (keys-from-pred
                 (lambda (var-meta)
                   (not (cider-browse-ns--meta-private-p var-meta)))
                 items))
               (private-keys (keys-from-pred #'cider-browse-ns--meta-private-p items)))
          (cider-browse-ns--display-list public-keys items max-length "Public")
          (cider-browse-ns--display-list private-keys items max-length "Private")))
       (t
        (cider-browse-ns--display-list
         (nrepl-dict-keys items) items max-length))))))