Function: cider-inspector--render-help

cider-inspector--render-help is a byte-compiled function defined in cider-inspector.el.

Signature

(cider-inspector--render-help)

Documentation

Render a keybinding help block at the bottom of the buffer.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-inspector.el
(defun cider-inspector--render-help ()
  "Render a keybinding help block at the bottom of the buffer."
  (save-excursion
    (let ((computed-items nil)
          (max-len 0))
      (goto-char (point-max))
      (insert "\n\n")
      (insert (propertize "--- Keybindings:\n" 'font-lock-face 'font-lock-comment-face))
      ;; Pre-compute key strings and calculate maximum length
      (dolist (cmd-pair cider-inspector--inline-help-data)
        (let* ((cmd (car cmd-pair))
               (desc (cdr cmd-pair))
               (keys (mapcar (lambda (k)
                               (propertize (key-description (where-is-internal k cider-inspector-mode-map t))
                                           'font-lock-face 'help-key-binding))
                             (if (atom cmd) (list cmd) cmd)))
               (key-str (string-join keys ", ")))
          (setq max-len (max max-len (length key-str)))
          (push (cons key-str desc) computed-items)))
      ;; Render lines with right-aligned padding.
      (dolist (item (nreverse computed-items))
        (let* ((key-str (car item))
               (desc (cdr item))
               (padding (make-string (- max-len (length key-str)) ?\s)))
          (insert "  " padding key-str
                  "  " (propertize desc 'font-lock-face 'font-lock-comment-face)
                  "\n"))))))