Function: consult-compile--candidates

consult-compile--candidates is a byte-compiled function defined in consult-compile.el.

Signature

(consult-compile--candidates GREP BUFFER)

Documentation

Return list of error candidate strings in BUFFER.

If GREP is non-nil, the buffer is a Grep buffer.

Source Code

;; Defined in ~/.emacs.d/elpa/consult-20260805.1130/consult-compile.el
(defun consult-compile--candidates (grep buffer)
  "Return list of error candidate strings in BUFFER.
If GREP is non-nil, the buffer is a Grep buffer."
  (with-current-buffer buffer
    (let ((pos (point-min)) candidates)
      (save-excursion
        (while (setq pos (compilation-next-single-property-change pos 'compilation-message))
          (when-let* ((msg (get-text-property pos 'compilation-message))
                      ((compilation--message->loc msg)))
            (goto-char pos)
            (let ((str (consult--buffer-substring pos (pos-eol))))
              (add-text-properties
               0 1 (list 'consult--type (unless grep
                                          (pcase (compilation--message->type msg)
                                            (0 ?i) (1 ?w) (_ ?e)))
                         'consult--candidate (point-marker))
               str)
              (push str candidates)))))
      (nreverse candidates))))