Function: defcustom-mode-local-semantic-dependency-system-include-path

defcustom-mode-local-semantic-dependency-system-include-path is a macro defined in dep.el.gz.

Signature

(defcustom-mode-local-semantic-dependency-system-include-path MODE NAME VALUE &optional DOCSTRING)

Documentation

Create a mode-local value of the system-dependency include path.

MODE is the major-mode this name/value pairs is for. NAME is the name of the customizable value users will use. VALUE is the path (a list of strings) to add. DOCSTRING is a documentation string applied to the variable NAME users will customize.

Creates a customizable variable users can customize that will keep semantic data structures up to date.

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/semantic/dep.el.gz
(defmacro defcustom-mode-local-semantic-dependency-system-include-path
  (mode name value &optional docstring)
  "Create a mode-local value of the system-dependency include path.
MODE is the `major-mode' this name/value pairs is for.
NAME is the name of the customizable value users will use.
VALUE is the path (a list of strings) to add.
DOCSTRING is a documentation string applied to the variable NAME
users will customize.

Creates a customizable variable users can customize that will
keep semantic data structures up to date."
  (declare (indent defun))
  `(progn
     ;; Create a variable users can customize.
     (defcustom ,name ,value
       ,docstring
       :group (quote ,(intern (car (split-string (symbol-name mode) "-"))))
       :group 'semantic
       :type '(repeat (directory :tag "Directory"))
       :set (lambda (sym val)
	      (set-default sym val)
	      (setq-mode-local ,mode
			       semantic-dependency-system-include-path
			       val)
	      (when (fboundp
		     'semantic-decoration-unparsed-include-do-reset)
		(mode-local-map-mode-buffers
		 'semantic-decoration-unparsed-include-do-reset
		 (quote ,mode))))
       )
     ;; Set the variable to the default value.
     (defvar-mode-local ,mode semantic-dependency-system-include-path
       ,name
       "System path to search for include files.")
     ;; Bind NAME onto our variable so tools can customize it
     ;; without knowing about it.
     (put 'semantic-dependency-system-include-path
	  (quote ,mode) (quote ,name))
     ))