Function: describe-input-method

describe-input-method is an interactive and byte-compiled function defined in mule-cmds.el.gz.

Signature

(describe-input-method INPUT-METHOD)

Documentation

Describe input method INPUT-METHOD.

View in manual

Probably introduced at or before Emacs version 24.4.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/international/mule-cmds.el.gz
(defun describe-input-method (input-method)
  "Describe input method INPUT-METHOD."
  (interactive
   (list (read-input-method-name
          (format-prompt "Describe input method" current-input-method))))
  (let ((help-buffer-under-preparation t))
    (if (and input-method (symbolp input-method))
	(setq input-method (symbol-name input-method)))
    (help-setup-xref (list #'describe-input-method
			   (or input-method current-input-method))
		     (called-interactively-p 'interactive))

    (if (null input-method)
	(describe-current-input-method)
      (let ((current current-input-method))
	(condition-case nil
	    (progn
	      (save-excursion
		(activate-input-method input-method)
		(describe-current-input-method))
	      (activate-input-method current))
	  (error
	   (activate-input-method current)
	   (help-setup-xref (list #'describe-input-method input-method)
			    (called-interactively-p 'interactive))
	   (with-output-to-temp-buffer (help-buffer)
	     (let ((elt (assoc input-method input-method-alist)))
	       (princ (format-message
		       "Input method: %s (`%s' in mode line) for %s\n  %s\n"
		       input-method (nth 3 elt) (nth 1 elt) (nth 4 elt)))))))))))