Function: dired-insert-set-properties

dired-insert-set-properties is a byte-compiled function defined in dired.el.gz.

Signature

(dired-insert-set-properties BEG END)

Documentation

Add various text properties to the lines in the region, from BEG to END.

Source Code

;; Defined in /usr/src/emacs/lisp/dired.el.gz
(defun dired-insert-set-properties (beg end)
  "Add various text properties to the lines in the region, from BEG to END."
  (save-excursion
    (goto-char beg)
    (while (< (point) end)
      (ignore-errors
	(if (not (dired-move-to-filename))
	    (unless (or (looking-at-p "^$")
			(looking-at-p dired-subdir-regexp))
	      (put-text-property (line-beginning-position)
				 (1+ (line-end-position))
				 'invisible 'dired-hide-details-information))
	  (put-text-property (+ (line-beginning-position) 1) (1- (point))
			     'invisible 'dired-hide-details-detail)
          (when (and dired-mouse-drag-files (fboundp 'x-begin-drag))
            (put-text-property (point)
                               (save-excursion
                                 (dired-move-to-end-of-filename)
                                 (backward-char)
                                 (point))
                               'keymap
                               dired-mouse-drag-files-map))
	  (add-text-properties
	   (point)
	   (progn
	     (dired-move-to-end-of-filename)
	     (point))
	   `(mouse-face
	     highlight
	     dired-filename t
	     help-echo ,(if (and dired-mouse-drag-files
                                 (fboundp 'x-begin-drag))
                            "down-mouse-1: drag this file to another program
mouse-2: visit this file in other window"
                          "mouse-2: visit this file in other window")))
	  (when (< (+ (point) 4) (line-end-position))
	    (put-text-property (+ (point) 4) (line-end-position)
			       'invisible 'dired-hide-details-link))))
      (forward-line 1))))