Function: ediff-meta-insert-file-info1

ediff-meta-insert-file-info1 is a byte-compiled function defined in ediff-mult.el.gz.

Signature

(ediff-meta-insert-file-info1 FILEINFO)

Source Code

;; Defined in /usr/src/emacs/lisp/vc/ediff-mult.el.gz
(defun ediff-meta-insert-file-info1 (fileinfo)
  (let ((fname (car fileinfo))
	(feq (ediff-get-file-eqstatus fileinfo))
	(max-filename-width (if ediff-meta-truncate-filenames
				(- (window-width) 41)
			      500))
	file-modtime file-size)
    (cond ((not (stringp fname)) (setq file-size -2)) ; file doesn't exits
	  ((ediff-listable-file fname)
	   (if (file-exists-p fname)
	       ;; set real size and modtime
	       (setq file-size (ediff-file-size fname)
		     file-modtime (ediff-file-modtime fname))
	     (setq file-size -2)))  ; file doesn't exist
	  ( t (setq file-size -1))) ; remote file
    (if (stringp fname)
	(insert
	 (format
	  "%s  %s   %-20s   %s\n"
	  (if feq "=" " ") ; equality indicator
	  (format "%10s" (cond ((= file-size -1) "--")
			       ((< file-size -1) "--")
			       (t file-size)))
	  (cond ((= file-size -1) "*remote file*")
		((< file-size -1) "*file doesn't exist*")
		(t (ediff-format-date (decode-time file-modtime))))

	  ;; dir names in meta lists have training slashes, so we just
	  ;; abbreviate the file name, if file exists
	  (if (and (not (stringp fname)) (< file-size -1))
	      "-------"		; file doesn't exist
	    (string-truncate-left
	     (ediff-abbreviate-file-name fname)
	     max-filename-width)))))))