Function: elide-head--hide

elide-head--hide is a byte-compiled function defined in elide-head.el.gz.

Signature

(elide-head--hide)

Documentation

Hide elided (hidden) headers.

Source Code

;; Defined in /usr/src/emacs/lisp/elide-head.el.gz
(defun elide-head--hide ()
  "Hide elided (hidden) headers."
  (save-excursion
    (save-restriction
      (let ((rest elide-head-headers-to-hide)
            beg end)
        (widen)
        (goto-char (point-min))
        (while rest
          (save-excursion
            (when (re-search-forward (caar rest) nil t)
              (setq beg (point))
              (when (re-search-forward (cdar rest) nil t)
                (setq end (point-marker)
                      rest nil))))
          (if rest (setq rest (cdr rest))))
        (if (not (and beg end))
            (if (called-interactively-p 'interactive)
                (message "No header found"))
          (goto-char beg)
          (end-of-line)
          (if (overlayp elide-head-overlay)
              (move-overlay elide-head-overlay (point-marker) end)
            (setq elide-head-overlay (make-overlay (point-marker) end)))
          (overlay-put elide-head-overlay 'invisible t)
          (overlay-put elide-head-overlay 'evaporate t)
          (overlay-put elide-head-overlay 'after-string "..."))))))