Function: elisp-demos--search

elisp-demos--search is a byte-compiled function defined in elisp-demos.el.

Signature

(elisp-demos--search SYMBOL)

Source Code

;; Defined in ~/.emacs.d/elpa/elisp-demos-20260826.1326/elisp-demos.el
(defun elisp-demos--search (symbol)
  (let (results)
    (dolist (file (append elisp-demos-user-files (list elisp-demos--elisp-demos.org)))
      (when (file-exists-p file)
        (with-temp-buffer
          (insert-file-contents file)
          (goto-char (point-min))
          (when (re-search-forward
                 (format "^\\* %s$" (regexp-quote (symbol-name symbol)))
                 nil t)
            (let (beg end)
              (forward-line 1)
              (setq beg (point))
              (if (re-search-forward "^\\*" nil t)
                  (setq end (line-beginning-position))
                (setq end (point-max)))
              (push (propertize
                     (string-trim (buffer-substring-no-properties beg end))
                     'file file
                     'pos beg)
                    results))))))
    (when results
      (string-join (nreverse results) "\n\n"))))