Function: epg--status-VALIDSIG

epg--status-VALIDSIG is a byte-compiled function defined in epg.el.gz.

Signature

(epg--status-VALIDSIG CONTEXT STRING)

Source Code

;; Defined in /usr/src/emacs/lisp/epg.el.gz
(defun epg--status-VALIDSIG (context string)
  (let ((signature (car (epg-context-result-for context 'verify))))
    (when (and signature
	       (eq (epg-signature-status signature) 'good)
	       (string-match "\\`\\([^ ]+\\) [^ ]+ \\([^ ]+\\) \\([^ ]+\\) \
\\([0-9]+\\) [^ ]+ \\([0-9]+\\) \\([0-9]+\\) \\([[:xdigit:]][[:xdigit:]]\\) \
\\(.*\\)"
			   string))
      (setf (epg-signature-fingerprint signature)
            (match-string 1 string))
      (setf (epg-signature-creation-time signature)
            (epg--time-from-seconds (match-string 2 string)))
      (unless (equal (match-string 3 string) "0")
	(setf (epg-signature-expiration-time signature)
              (epg--time-from-seconds (match-string 3 string))))
      (setf (epg-signature-version signature)
            (string-to-number (match-string 4 string)))
      (setf (epg-signature-pubkey-algorithm signature)
            (string-to-number (match-string 5 string)))
      (setf (epg-signature-digest-algorithm signature)
            (string-to-number (match-string 6 string)))
      (setf (epg-signature-class signature)
            (string-to-number (match-string 7 string) 16)))))