Function: epg-signature-to-string

epg-signature-to-string is a byte-compiled function defined in epg.el.gz.

Signature

(epg-signature-to-string SIGNATURE)

Documentation

Convert SIGNATURE to a human readable string.

Source Code

;; Defined in /usr/src/emacs/lisp/epg.el.gz
(defun epg-signature-to-string (signature)
  "Convert SIGNATURE to a human readable string."
  (let* ((user-id (cdr (assoc (epg-signature-key-id signature)
			      epg-user-id-alist)))
	 (pubkey-algorithm (epg-signature-pubkey-algorithm signature))
	 (key-id (epg-signature-key-id signature)))
    (concat
     (cl-case (epg-signature-status signature)
       (good "Good signature from ")
       (bad "Bad signature from ")
       (expired "Expired signature from ")
       (expired-key "Signature made by expired key ")
       (revoked-key "Signature made by revoked key ")
       (no-pubkey "No public key for "))
     key-id
     (and user-id
	  (concat " "
		  (if (stringp user-id)
                      (if (= (length user-id) (string-bytes user-id))
                          ;; This is ASCII, possibly %-encoded.
                          (rfc6068-unhexify-string user-id)
                        ;; Non-ASCII, return as is.
                        user-id)
		    (epg-decode-dn user-id))))
     (and (epg-signature-validity signature)
	  (format " (trust %s)"  (epg-signature-validity signature)))
     (and (epg-signature-creation-time signature)
	  (format-time-string " created at %Y-%m-%dT%T%z"
			      (epg-signature-creation-time signature)))
     (and pubkey-algorithm
	  (concat " using "
		  (or (cdr (assq pubkey-algorithm epg-pubkey-algorithm-alist))
		      (format "(unknown algorithm %d)" pubkey-algorithm)))))))