Function: erc-display-message

erc-display-message is a byte-compiled function defined in erc.el.gz.

Signature

(erc-display-message PARSED TYPE BUFFER MSG &rest ARGS)

Documentation

Display MSG in BUFFER.

ARGS, PARSED, and TYPE are used to format MSG sensibly.

See also erc-format-message and erc-display-line.

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc.el.gz
(defun erc-display-message (parsed type buffer msg &rest args)
  "Display MSG in BUFFER.

ARGS, PARSED, and TYPE are used to format MSG sensibly.

See also `erc-format-message' and `erc-display-line'."
  (let ((string (if (symbolp msg)
                    (apply #'erc-format-message msg args)
                  msg))
        (erc-message-parsed parsed))
    (setq string
          (cond
           ((null type)
            string)
           ((listp type)
            (mapc (lambda (type)
                    (setq string
                          (erc-display-message-highlight type string)))
                  type)
            string)
           ((symbolp type)
            (erc-display-message-highlight type string))))

    (if (not (erc-response-p parsed))
        (erc-display-line string buffer)
      (unless (erc-hide-current-message-p parsed)
        (erc-put-text-property 0 (length string) 'erc-parsed parsed string)
        (erc-put-text-property 0 (length string) 'rear-sticky t string)
	(when (erc-response.tags parsed)
	  (erc-put-text-property 0 (length string) 'tags (erc-response.tags parsed)
				 string))
	(erc-display-line string buffer)))))