Function: evil-read-digraph-char-with-overlay

evil-read-digraph-char-with-overlay is an interactive and byte-compiled function defined in evil-common.el.

Signature

(evil-read-digraph-char-with-overlay OVERLAY)

Documentation

Read two chars, displaying the first in OVERLAY, replacing "?".

Return the digraph from evil-digraph, else return second char.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/evil-20251108.138/evil-common.el
(defun evil-read-digraph-char-with-overlay (overlay)
  "Read two chars, displaying the first in OVERLAY, replacing \"?\".
Return the digraph from `evil-digraph', else return second char."
  (interactive)
  (unwind-protect
      (let ((read-key-empty-map
             (let ((map (copy-keymap evil-digraph-read-key-keymap)))
               (set-keymap-parent map read-key-empty-map)
               ;; Disable read-key-sequence unbound fallbacks, e.g. downcasing
               (define-key map [t] 'dummy)
               map))
            char1 char2)
        ;; create overlay prompt
        (overlay-put overlay 'invisible t)
        (overlay-put overlay 'after-string
                     #("?" 0 1 (face minibuffer-prompt cursor 1)))
        (setq char1 (read-key))
        (overlay-put overlay 'after-string
                     (propertize (char-to-string char1)
                                 'face 'minibuffer-prompt
                                 'cursor 1))
        (setq char2 (read-key))

        (or (evil-digraph (list char1 char2))
            ;; use the last character if undefined
            char2))
    (delete-overlay overlay)))