Function: font-show-log

font-show-log is an autoloaded, interactive and byte-compiled function defined in mule-diag.el.gz.

Signature

(font-show-log &optional LIMIT)

Documentation

Show log of font listing and opening.

Prefix arg LIMIT says how many fonts to show for each listing. The default is 20. If LIMIT is negative, do not limit the listing.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/international/mule-diag.el.gz
;;;###autoload
(defun font-show-log (&optional limit)
  "Show log of font listing and opening.
Prefix arg LIMIT says how many fonts to show for each listing.
The default is 20.  If LIMIT is negative, do not limit the listing."
  (interactive "P")
  (setq limit (if limit (prefix-numeric-value limit) 20))
  (if (eq font-log t)
      (message "Font logging is currently suppressed")
    (with-output-to-temp-buffer "*Help*"
      (set-buffer standard-output)
      (dolist (elt (reverse font-log))
	(insert (format "%s: %s\n" (car elt) (cadr elt)))
	(setq elt (nth 2 elt))
	(if (or (vectorp elt) (listp elt))
	    (let ((i 0))
	      (catch 'tag
                (mapc (lambda (x)
                        (setq i (1+ i))
                        (when (= i limit)
                          (insert "  ...\n")
                          (throw 'tag nil))
                        (insert (format "  %s\n" x)))
		      elt)))
	  (insert (format "  %s\n" elt)))))))