Function: forms--make-format-elt

forms--make-format-elt is a byte-compiled function defined in forms.el.gz.

Signature

(forms--make-format-elt EL)

Documentation

Helper routine to generate format function.

Source Code

;; Defined in /usr/src/emacs/lisp/forms.el.gz
(defun forms--make-format-elt (el)
  "Helper routine to generate format function."

  ;; If we're not using text properties, the format routine
  ;; `forms--format' will look like
  ;;
  ;; (lambda (arg)
  ;;   ;; a string, e.g. "text: "
  ;;   (insert "text: ")
  ;;   ;; a field, e.g. 6
  ;;   (aset forms--markers 0 (point-marker))
  ;;   (insert (elt arg 5))
  ;;   ;; another string, e.g. "\nmore text: "
  ;;   (insert "\nmore text: ")
  ;;   ;; a function, e.g. (tocol 40)
  ;;   (insert (aset forms--dyntexts 0 (tocol 40)))
  ;;   ... )

  (cond
   ((stringp el)
    `((insert ,el)))
   ((numberp el)
    (prog1
	`((aset forms--markers ,forms--marker (point-marker))
	  (insert (elt arg ,(1- el))))
      (setq forms--marker (1+ forms--marker))))
   ((listp el)
    (prog1
	`((insert (aset forms--dyntexts ,forms--dyntext ,el)))
      (setq forms--dyntext (1+ forms--dyntext))))))