Function: function-called-at-point

function-called-at-point is a byte-compiled function defined in help.el.gz.

Signature

(function-called-at-point)

Documentation

Return a function around point or else called by the list containing point.

If that doesn't give a function, return nil.

Source Code

;; Defined in /usr/src/emacs/lisp/help.el.gz
(defun function-called-at-point ()
  "Return a function around point or else called by the list containing point.
If that doesn't give a function, return nil."
  (with-syntax-table emacs-lisp-mode-syntax-table
    (or (condition-case ()
            (save-excursion
              (or (not (zerop (skip-syntax-backward "_w")))
                  (eq (char-syntax (following-char)) ?w)
                  (eq (char-syntax (following-char)) ?_)
                  (forward-sexp -1))
              (skip-chars-forward "'")
              (let ((obj (read (current-buffer))))
                (and (symbolp obj) (fboundp obj) obj)))
          (error nil))
        (condition-case ()
            (save-excursion
              (save-restriction
                (let ((forward-sexp-function nil)) ;Use elisp-mode's value
                  (narrow-to-region (max (point-min)
                                         (- (point) 1000))
                                    (point-max))
                  ;; Move up to surrounding paren, then after the open.
                  (backward-up-list 1)
                  (forward-char 1)
                  ;; If there is space here, this is probably something
                  ;; other than a real Lisp function call, so ignore it.
                  (if (looking-at "[ \t]")
                      (error "Probably not a Lisp function call"))
                  (let ((obj (read (current-buffer))))
                    (and (symbolp obj) (fboundp obj) obj)))))
          (error nil))
        (let* ((str (find-tag-default))
               (sym (if str (intern-soft str))))
          (if (and sym (fboundp sym))
              sym
            (save-match-data
              (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
                (setq sym (intern-soft (match-string 1 str)))
                (and (fboundp sym) sym))))))))