Function: gnus-async-article-callback

gnus-async-article-callback is a byte-compiled function defined in gnus-async.el.gz.

Signature

(gnus-async-article-callback ARG GROUP ARTICLE MARK SUMMARY NEXT)

Documentation

Function called when an async article is done being fetched.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-async.el.gz
(defun gnus-async-article-callback (arg group article mark summary next)
  "Function called when an async article is done being fetched."
  (save-excursion
    (setq gnus-async-current-prefetch-article nil)
    (when arg
      (gnus-async-set-buffer)
      (save-excursion
	(save-restriction
	  (narrow-to-region mark (point-max))
	  ;; Put the articles into the agent, if they aren't already.
	  (when (and gnus-agent
		     gnus-agent-eagerly-store-articles
		     (gnus-agent-group-covered-p group))
	    (save-restriction
	      (narrow-to-region mark (point-max))
	      (gnus-agent-store-article article group)))
	  ;; Prefetch images for the groups that want that.
	  (when (fboundp 'gnus-html-prefetch-images)
	    (gnus-html-prefetch-images summary))
	  (when gnus-async-post-fetch-function
	    (funcall gnus-async-post-fetch-function summary))))
      (gnus-async-with-semaphore
	(push (list (format "%s-%d" group article)
		    mark (point-max-marker)
		    group article)
	      gnus-async-article-alist)))
    (if (not (gnus-buffer-live-p summary))
	(gnus-async-with-semaphore
	  (setq gnus-async-fetch-list nil))
      (gnus-async-prefetch-article group next summary t))))