Function: gnus-backlog-remove-article

gnus-backlog-remove-article is an autoloaded and byte-compiled function defined in gnus-bcklg.el.gz.

Signature

(gnus-backlog-remove-article GROUP NUMBER)

Documentation

Remove article NUMBER in GROUP from the backlog.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-bcklg.el.gz
(defun gnus-backlog-remove-article (group number)
  "Remove article NUMBER in GROUP from the backlog."
  (when (numberp number)
    (let ((ident (format "%s:%d" group number))
	  beg)
      (when (member ident gnus-backlog-articles)
	;; It was in the backlog.
	(with-current-buffer (gnus-backlog-buffer)
	  (save-excursion
	    (let (buffer-read-only)
	      (goto-char (point-min))
	      (when (setq beg (gnus-text-property-search
			       'gnus-backlog ident))
		;; Find the end (i. e., the beginning of the next article).
		(goto-char
		 (next-single-property-change
		  (1+ beg) 'gnus-backlog (current-buffer) (point-max)))
		(delete-region beg (point))
		;; Return success.
		t)))
	  (setq gnus-backlog-articles
		(delete ident gnus-backlog-articles)))))))