Function: gnus-bookmark-bmenu-list

gnus-bookmark-bmenu-list is an autoloaded, interactive and byte-compiled function defined in gnus-bookmark.el.gz.

Signature

(gnus-bookmark-bmenu-list)

Documentation

Display a list of existing Gnus bookmarks.

The list is displayed in a buffer named *Gnus Bookmark List*. The leftmost column displays a D if the bookmark is flagged for deletion, or > if it is flagged for displaying.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-bookmark.el.gz
;;;###autoload
(defun gnus-bookmark-bmenu-list ()
  "Display a list of existing Gnus bookmarks.
The list is displayed in a buffer named `*Gnus Bookmark List*'.
The leftmost column displays a D if the bookmark is flagged for
deletion, or > if it is flagged for displaying."
  (interactive)
  (gnus-bookmark-maybe-load-default-file)
  (if (called-interactively-p 'any)
      (switch-to-buffer (gnus-get-buffer-create "*Gnus Bookmark List*"))
    (set-buffer (gnus-get-buffer-create "*Gnus Bookmark List*")))
  (let ((inhibit-read-only t)
	alist name) ;; start end
    (erase-buffer)
    (insert "% Gnus Bookmark\n- --------\n")
    (add-text-properties (point-min) (point)
			 '(font-lock-face gnus-bookmark-menu-heading))
    ;; sort before displaying
    (gnus-bookmark-maybe-sort-alist)
    ;; Display gnus bookmarks
    (setq alist gnus-bookmark-alist)
    (while alist
      (setq name (gnus-bookmark-name-from-full-record (pop alist)))
      ;; if a Gnus bookmark has an annotation, prepend a "*"
      ;; in the list of bookmarks.
      (insert (if (member (gnus-bookmark-get-annotation name) (list nil ""))
		  "  "
		" *"))
      (if (display-mouse-p)
	  (add-text-properties
	   (prog1
	       (point)
	     (insert name))
	   (let ((end (point)))
	     (prog2
		 (re-search-backward "[^ \t]")
		 (1+ (point))
	       (goto-char end)
	       (insert "\n")))
	   `(mouse-face highlight follow-link t
			help-echo ,(format "%s: go to this article"
					   'mouse-2)))
	(insert name "\n")))
    (goto-char (point-min))
    (forward-line 2)
    (gnus-bookmark-bmenu-mode)
    (if gnus-bookmark-bmenu-toggle-infos
	(gnus-bookmark-bmenu-toggle-infos t))))