Function: gnus-group-describe-all-groups

gnus-group-describe-all-groups is an interactive and byte-compiled function defined in gnus-group.el.gz.

Signature

(gnus-group-describe-all-groups &optional FORCE)

Documentation

Pop up a buffer with descriptions of all newsgroups.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-group.el.gz
;; Suggested by Per Abrahamsen <amanda@iesd.auc.dk>.
(defun gnus-group-describe-all-groups (&optional force)
  "Pop up a buffer with descriptions of all newsgroups."
  (interactive "P" gnus-group-mode)
  (when force
    (setq gnus-description-hashtb nil))
  (when (not (or gnus-description-hashtb
		 (gnus-read-all-descriptions-files)))
    (error "Couldn't request descriptions file"))
  (let ((buffer-read-only nil))
    (erase-buffer)
    (dolist (group (sort (hash-table-keys gnus-description-hashtb) #'string<))
      (let ((b (point))
            (desc (gethash group gnus-description-hashtb))
            (charset (gnus-group-name-charset nil group)))
	(insert (format "      *: %-20s %s\n"
			(gnus-group-name-decode group charset)
                        (gnus-group-name-decode desc charset)))
        (add-text-properties
         b (1+ b) (list 'gnus-group group
                        'gnus-unread t 'gnus-marked nil
                        'gnus-level (1+ gnus-level-subscribed)))))
    (goto-char (point-min))
    (gnus-group-position-point)))