Function: gnus-outlook-rearrange-article

gnus-outlook-rearrange-article is a byte-compiled function defined in deuglify.el.gz.

Signature

(gnus-outlook-rearrange-article ATTR-START)

Documentation

Put text from ATTR-START to the end of buffer at the top of the article buffer.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/deuglify.el.gz
(defun gnus-outlook-rearrange-article (attr-start)
  "Put text from ATTR-START to the end of buffer at the top of the article buffer."
  ;; FIXME: 1.  (*) text/plain          ( ) text/html
  (let ((inhibit-read-only t)
	;; (cite-marks gnus-outlook-deuglify-cite-marks)
	)
    (gnus-with-article-buffer
      (article-goto-body)
      ;; article does not start with attribution
      (unless (= (point) attr-start)
	(gnus-kill-all-overlays)
	(let ((cur (point))
	      ;; before signature or end of buffer
	      (to (if (gnus-article-search-signature)
		      (point)
		    (point-max))))
	  ;; handle the case where the full quote is below the
	  ;; signature
	  (when (< to attr-start)
	    (setq to (point-max)))
	  (save-excursion
	    (narrow-to-region attr-start to)
	    (goto-char attr-start)
	    (forward-line)
	    (unless (looking-at ">")
	      (message-indent-citation (point) (point-max) 'yank-only)
	      (goto-char (point-max))
	      (newline)
	      (setq to (point-max)))
	    (widen))
	  (transpose-regions cur attr-start attr-start to))))))