Function: gnus-read-newsrc-el-file

gnus-read-newsrc-el-file is a byte-compiled function defined in gnus-start.el.gz.

Signature

(gnus-read-newsrc-el-file FILE)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-start.el.gz
(defun gnus-read-newsrc-el-file (file)
  (let ((ding-file (concat file "d")))
    (when (file-exists-p ding-file)
      ;; We always, always read the .eld file.
      (gnus-message 5 "Reading %s..." ding-file)
      (let (gnus-newsrc-assoc)
	(gnus-load ding-file)
	;; Older versions of `gnus-format-specs' are no longer valid
	;; in Oort Gnus 0.01.
	(let ((version
	       (and gnus-newsrc-file-version
		    (gnus-continuum-version gnus-newsrc-file-version))))
	  (when (or (not version)
		    (< version 5.090009))
	    (setq gnus-format-specs gnus-default-format-specs)))
	(when gnus-newsrc-assoc
	  (setq gnus-newsrc-alist gnus-newsrc-assoc))))
    (gnus-make-hashtable-from-newsrc-alist)
    (when gnus-topic-alist
      (setq gnus-topic-alist
	    (mapcar
	     (lambda (elt)
	       (cons (car elt)
		     (mapcar (lambda (g)
			       (if (string-match-p "[^[:ascii:]]" g)
				   (gnus-group-decoded-name g)
				 g))
			     (cdr elt))))
	     gnus-topic-alist)))
    (when (file-newer-than-file-p file ding-file)
      ;; Old format quick file
      (gnus-message 5 "Reading %s..." file)
      ;; The .el file is newer than the .eld file, so we read that one
      ;; as well.
      (gnus-read-old-newsrc-el-file file)))
  (gnus-run-hooks 'gnus-read-newsrc-el-hook))