Function: gnus-summary-setup-buffer

gnus-summary-setup-buffer is a byte-compiled function defined in gnus-sum.el.gz.

Signature

(gnus-summary-setup-buffer GROUP)

Documentation

Initialize summary buffer for GROUP.

This function does all setup work that relies on the specific value of GROUP, and puts the buffer in gnus-summary-mode.

Returns non-nil if the setup was successful.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-sum.el.gz
(defun gnus-summary-setup-buffer (group)
  "Initialize summary buffer for GROUP.
This function does all setup work that relies on the specific
value of GROUP, and puts the buffer in `gnus-summary-mode'.

Returns non-nil if the setup was successful."
  (let ((buffer (gnus-summary-buffer-name group))
	(dead-name (concat "*Dead Summary " group "*")))
    ;; If a dead summary buffer exists, we kill it.
    (gnus-kill-buffer dead-name)
    (if (get-buffer buffer)
	(progn
	  (set-buffer buffer)
	  (setq gnus-summary-buffer (current-buffer))
	  (not gnus-newsgroup-prepared))
      (set-buffer (gnus-get-buffer-create buffer))
      (setq gnus-summary-buffer (current-buffer))
      (let ((gnus-summary-mode-group group))
       (gnus-summary-mode))
      (when (gnus-group-quit-config group)
        (setq-local gnus-single-article-buffer nil))
      (turn-on-gnus-mailing-list-mode)
      ;; These functions don't currently depend on GROUP, but might in
      ;; the future.
      (gnus-update-format-specifications nil 'summary 'summary-mode 'summary-dummy)
      (gnus-update-summary-mark-positions)
      ;; Set any local variables in the group parameters.
      (gnus-summary-set-local-parameters gnus-newsgroup-name)
      t)))