Function: gnus-uu-decode-postscript-article

gnus-uu-decode-postscript-article is a byte-compiled function defined in gnus-uu.el.gz.

Signature

(gnus-uu-decode-postscript-article PROCESS-BUFFER IN-STATE)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-uu.el.gz
;; PostScript

(defun gnus-uu-decode-postscript-article (process-buffer _in-state)
  (let ((state (list 'ok))
	start-char end-char file-name)
    (with-current-buffer process-buffer
      (goto-char (point-min))
      (if (not (re-search-forward gnus-uu-postscript-begin-string nil t))
	  (setq state (list 'wrong-type))
	(beginning-of-line)
	(setq start-char (point))
	(if (not (re-search-forward gnus-uu-postscript-end-string nil t))
	    (setq state (list 'wrong-type))
	  (setq end-char (point))
	  (set-buffer (gnus-get-buffer-create gnus-uu-output-buffer-name))
	  (insert-buffer-substring process-buffer start-char end-char)
	  (setq file-name (concat gnus-uu-work-dir
				  (cdr gnus-article-current) ".ps"))
	  (write-region (point-min) (point-max) file-name)
	  (setq state (list file-name 'begin 'end)))))
    state))