Function: hangul-to-hanja-conversion

hangul-to-hanja-conversion is an interactive and byte-compiled function defined in hangul.el.gz.

Signature

(hangul-to-hanja-conversion)

Documentation

Convert the previous hangul character to the corresponding hanja character.

When a Korean input method is off, convert the following hangul character.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/leim/quail/hangul.el.gz
(defun hangul-to-hanja-conversion ()
  "Convert the previous hangul character to the corresponding hanja character.
When a Korean input method is off, convert the following hangul character."
  (interactive)
  (let ((echo-keystrokes 0)
        delete-func
        hanja-character)
    (if (and (overlayp quail-overlay) (overlay-start quail-overlay))
        (progn
	  (setq hanja-character (hangul-to-hanja-char (preceding-char)))
	  (setq delete-func (lambda () (delete-char -1))))
      (setq hanja-character (hangul-to-hanja-char (following-char)))
      (setq delete-func (lambda () (delete-char 1))))
    (when hanja-character
      (funcall delete-func)
      (insert hanja-character)
      (setq hangul-queue (make-vector 6 0))
      (if (and (overlayp quail-overlay) (overlay-start quail-overlay))
	  (move-overlay quail-overlay (point) (point))))))