Function: hangul3-input-method

hangul3-input-method is a byte-compiled function defined in hangul.el.gz.

Signature

(hangul3-input-method KEY)

Documentation

3-Bulsik final input method.

Source Code

;; Defined in /usr/src/emacs/lisp/leim/quail/hangul.el.gz
(defun hangul3-input-method (key)
  "3-Bulsik final input method."
  (if (or buffer-read-only (< key 33) (>= key 127))
      (list key)
    (quail-setup-overlays nil)
    (let ((input-method-function nil)
	  (echo-keystrokes 0)
	  (help-char nil))
      (setq hangul-queue (make-vector 6 0))
      (hangul3-input-method-internal key)
      (unwind-protect
	  (catch 'exit-input-loop
	    (while t
	      (let* ((seq (read-key-sequence nil))
		     (cmd (lookup-key hangul-im-keymap seq))
		     key)
		(cond ((and (stringp seq)
			    (= 1 (length seq))
			    (setq key (aref seq 0))
			    (and (>= key 33) (< key 127)))
		       (hangul3-input-method-internal key))
		      ((commandp cmd)
		       (call-interactively cmd))
		      (t
		       (setq unread-command-events
                             (nconc (listify-key-sequence seq)
                                    unread-command-events))
		       (throw 'exit-input-loop nil))))))
	(quail-delete-overlays)))))