Function: hanja-list-show

hanja-list-show is a byte-compiled function defined in hanja-util.el.gz.

Signature

(hanja-list-show)

Documentation

Show hanja list in the echo area.

Source Code

;; Defined in /usr/src/emacs/lisp/language/hanja-util.el.gz
(defun hanja-list-show ()
  "Show hanja list in the echo area."
  (let* ((base (aref hanja-conversions 0))
         (offset (aref hanja-conversions 1))
         (hanja-list (aref hanja-conversions 2))
         (partial-hanja-list (nthcdr (* base hanja-list-width)
                                     hanja-list))
         (idx 0)
         (msg "")
         (message-log-max nil)
         char-meaning)
    (while (and (< idx hanja-list-width)
                partial-hanja-list)
      (setq msg (format "%s%d.%c " msg idx (car (car partial-hanja-list))))
      (when (= offset idx)
        (put-text-property
         (+ 2 (string-match (format "%d\\.[^ ]*" idx) msg))
         (match-end 0)
         'face 'highlight msg)
        (setq char-meaning (cdr (car partial-hanja-list))))
      (setq idx (1+ idx)
            partial-hanja-list (cdr partial-hanja-list)))
    (if char-meaning
        (setq msg (format "%s   (뜻 : %s)" msg char-meaning)))
    (message "%s" msg)))