Function: help--describe-command

help--describe-command is a byte-compiled function defined in help.el.gz.

Signature

(help--describe-command DEFINITION &optional TRANSLATION)

Aliases

help--describe-translation (obsolete since 29.1)

Source Code

;; Defined in /usr/src/emacs/lisp/help.el.gz
(defun help--describe-command (definition &optional translation)
  (cond ((symbolp definition)
         (if (and (fboundp definition)
                  help-buffer-under-preparation)
             (insert-text-button (symbol-name definition)
                                 'type 'help-function
                                 'help-args (list definition))
           (insert (symbol-name definition)))
         (insert "\n"))
        ((or (stringp definition) (vectorp definition))
         (if translation
             (insert (key-description definition nil) "\n")
           (insert "Keyboard Macro\n")))
        ((keymapp definition)
         (insert "Prefix Command\n"))
        ((byte-code-function-p definition)
         (insert (format "[%s]\n"
                         (buttonize "byte-code" #'disassemble definition))))
        ((and (consp definition)
              (memq (car definition) '(closure lambda)))
         (insert (format "[%s]\n"
                         (buttonize
                          (symbol-name (car definition))
                          (lambda (_)
                            (pp-display-expression
                             definition "*Help Source*" t))
                          nil "View definition"))))
        (t
         (insert "??\n"))))