Function: hmouse-mod-execute-command

hmouse-mod-execute-command is a byte-compiled function defined in hmouse-mod.el.

Signature

(hmouse-mod-execute-command KEY COUNT)

Documentation

Execute command on keyboard KEY or if KEY is a prefix, record it.

Second argument COUNT is used as a prefix argument to the command.

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hmouse-mod.el
(defun hmouse-mod-execute-command (key count)
  "Execute command on keyboard KEY or if KEY is a prefix, record it.
Second argument COUNT is used as a prefix argument to the command."
  (if (stringp key) (setq key (concat hmouse-mod--prefix key)))
  (let ((binding (key-binding key))
	(current-prefix-arg count))
    (cond ((and (not (or (vectorp binding) (stringp binding)))
		(commandp binding))
	   (if (> (length key) 1)
	       (or noninteractive (message (key-description key))))
	   (setq hmouse-mod--prefix nil)
	   (call-interactively
	    (if (eq binding 'hmouse-mod-insert-command)
		#'self-insert-command
	      binding)))
	  ((symbolp binding)
	   (setq hmouse-mod--prefix nil)
	   (error "(hmouse-mod-execute-command): {%s} not bound to a command"
		  key))
	  ((integerp binding)
	   (setq hmouse-mod--prefix nil)
	   (error "(hmouse-mod-execute-command): {%s} invalid key sequence"
		  (key-description (vector key))))
	  ((stringp key)
	   (or noninteractive (message (key-description key)))
	   (setq hmouse-mod--prefix key))
	  (t ;; Unrecognized key type, log an error message
	   (beep)
	   (message "(HyDebug): hmouse-mod-execute-command - `%s' invalid key" key)))))