Function: holiday-hebrew-misc

holiday-hebrew-misc is a byte-compiled function defined in cal-hebrew.el.gz.

Signature

(holiday-hebrew-misc)

Documentation

Miscellaneous Hebrew holidays, if visible in calendar window.

Includes: Tal Umatar, Tzom Teveth, Tu B'Shevat, Shabbat Shirah, and Kiddush HaHamah.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-hebrew.el.gz
;;;###holiday-autoload
(defun holiday-hebrew-misc ()
  "Miscellaneous Hebrew holidays, if visible in calendar window.
Includes: Tal Umatar, Tzom Teveth, Tu B'Shevat, Shabbat Shirah, and
Kiddush HaHamah."
  (let ((m displayed-month)
        (y displayed-year)
        year h-year)
    (append
     (holiday-julian
      11
      (progn
        (calendar-increment-month m y -1)
        (setq year (calendar-extract-year
                    (calendar-julian-from-absolute
                     (calendar-absolute-from-gregorian (list m 1 y)))))
        (if (zerop (% (1+ year) 4))
            22
          21)) "\"Tal Umatar\" (evening)")
     (holiday-hebrew
      10
      (progn
        (setq h-year (calendar-extract-year
                      (calendar-hebrew-from-absolute
                       (calendar-absolute-from-gregorian
                        (list displayed-month 28 displayed-year)))))
        (if (= 6 (% (calendar-hebrew-to-absolute (list 10 10 h-year))
                    7))
            11 10))
      "Tzom Teveth")
     (holiday-hebrew 11 15 "Tu B'Shevat")
     (holiday-hebrew
      11
      (progn
        (setq m displayed-month
              y displayed-year
              h-year (progn
                       (calendar-increment-month m y 1)
                       (calendar-extract-year
                        (calendar-hebrew-from-absolute
                         (calendar-absolute-from-gregorian
                          (list m (calendar-last-day-of-month m y) y))))))
        (calendar-extract-day
         (calendar-hebrew-from-absolute
          (calendar-dayname-on-or-before
           6 (calendar-hebrew-to-absolute
              (list 11
                    (if (= 6
                           (% (calendar-hebrew-to-absolute
                               (list 7 1 h-year))
                              7))
                        17 16) h-year))))))
      "Shabbat Shirah")
     (and (progn
            (setq m displayed-month
                  y displayed-year
                  year (progn
                         (calendar-increment-month m y -1)
                         (calendar-extract-year
                          (calendar-julian-from-absolute
                           (calendar-absolute-from-gregorian (list m 1 y))))))
            (= 21 (% year 28)))
          (holiday-julian 3 26 "Kiddush HaHamah")))))