Function: hyrolo-name-at-p

hyrolo-name-at-p is a byte-compiled function defined in hyrolo.el.

Signature

(hyrolo-name-at-p)

Documentation

Iff point is at or within an entry in hyrolo-display-buffer, return non-nil.

Any non-nil value returned is a cons of (<entry-name> . <entry-source>).

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hyrolo.el
(defun hyrolo-name-at-p ()
  "Iff point is at or within an entry in `hyrolo-display-buffer', return non-nil.
Any non-nil value returned is a cons of (<entry-name> . <entry-source>)."
  (when (eq (current-buffer) (get-buffer hyrolo-display-buffer))
    (let ((entry-source (hbut:get-key-src t))
	  (col-num (current-column))
	  (line-start (line-beginning-position))
	  (line-end (line-end-position)))
      (when entry-source
	(save-excursion
	  (forward-line 0)
	  (let (case-fold-search
		entry-line
		entry-name)
	    (if (and (or (looking-at hyrolo-hdr-and-entry-regexp)
			 (re-search-backward hyrolo-hdr-and-entry-regexp nil t))
		     (save-match-data (not (looking-at hyrolo-hdr-regexp))))
		(progn (goto-char (match-end 0))
		       (skip-chars-forward " \t")
		       (when (or (looking-at "[^ \t\n\r]+ ?, ?[^ \t\n\r]+")
				 (looking-at "\\( ?[^ \t\n\r]+\\)+"))
			 (setq entry-name (match-string-no-properties 0)
			       entry-line (buffer-substring-no-properties line-start line-end))
			 ;; Add a text-property of :hyrolo-name-entry with
			 ;; value of (entry-line . current-column) to entry-name.
			 (put-text-property 0 1 :hyrolo-name-entry
					    (cons entry-line col-num)
					    entry-name)
			 (cons entry-name entry-source)))
	      ;; If not blank, return the current line as the name with
	      ;; a text-property of 'hyrolo-line-entry with value of (current-column).
	      (goto-char line-start)
	      (when (not (looking-at "[ \t\f]*$"))
		(setq entry-line (buffer-substring-no-properties line-start line-end))
		(put-text-property 0 1 'hyrolo-line-entry col-num entry-line)
		(cons entry-line entry-source)))))))))