Function: idlwave-shell-make-new-bp-overlay

idlwave-shell-make-new-bp-overlay is a byte-compiled function defined in idlw-shell.el.gz.

Signature

(idlwave-shell-make-new-bp-overlay &optional TYPE DISABLED)

Documentation

Make a new overlay for highlighting breakpoints.

This stuff is strongly dependent upon the version of Emacs. If TYPE is passed, make an overlay of that type (bp or bp-cond, currently only for glyphs).

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/idlw-shell.el.gz
(defun idlwave-shell-make-new-bp-overlay (&optional type disabled)
  "Make a new overlay for highlighting breakpoints.

This stuff is strongly dependent upon the version of Emacs.  If TYPE
is passed, make an overlay of that type (`bp' or `bp-cond', currently
only for glyphs)."
  (let ((ov (make-overlay 1 1))
	(use-glyph (and (memq idlwave-shell-mark-breakpoints '(t glyph))
			idlwave-shell-bp-glyph))
	(type (or type 'bp))
	(face (if disabled
		  idlwave-shell-disabled-breakpoint-face
		idlwave-shell-breakpoint-face)))
    (when idlwave-shell-breakpoint-popup-menu
      (overlay-put ov 'mouse-face 'highlight)
      (overlay-put ov 'keymap idlwave-shell-debug-line-map))
    (cond
     (window-system
      (if use-glyph
	  (let ((image-props (cdr (assq type idlwave-shell-bp-glyph)))
		string)

	    (if disabled (setq image-props
			       (append image-props
				       (list :conversion 'disabled))))
	    (setq string
		  (propertize "@"
			      'display
			      (list (list 'margin 'left-margin)
				    image-props)))
	    (overlay-put ov 'before-string string))
	;; just the face
	(overlay-put ov 'face face)))

     ;; use a face
     (idlwave-shell-mark-breakpoints
      (overlay-put ov 'face face))

     ;; No marking
     (t nil))
    ov))