Function: ido-ignore-item-p

ido-ignore-item-p is a byte-compiled function defined in ido.el.gz.

Signature

(ido-ignore-item-p NAME RE-LIST &optional IGNORE-EXT)

Documentation

Return t if the buffer or file NAME should be ignored.

Source Code

;; Defined in /usr/src/emacs/lisp/ido.el.gz
(defun ido-ignore-item-p (name re-list &optional ignore-ext)
  "Return t if the buffer or file NAME should be ignored."
  (or (and (member name ido-ignore-item-temp-list) t)
      (and
       ido-process-ignore-lists re-list
       (save-match-data
	 (let ((ext-list (and ignore-ext ido-ignore-extensions
			      completion-ignored-extensions))
	       (case-fold-search ido-case-fold)
	       ignorep nextstr
	       (flen (length name)) slen)
	   (while ext-list
	     (setq nextstr (car ext-list))
	     (if (cond
		  ((stringp nextstr)
		   (and (>= flen (setq slen (length nextstr)))
			(string-equal (substring name (- flen slen)) nextstr)))
		  ((functionp nextstr) (funcall nextstr name))
		  (t nil))
		 (setq ignorep t
		       ext-list nil
		       re-list nil)
	       (setq ext-list (cdr ext-list))))
	   (while re-list
	     (setq nextstr (car re-list))
	     (if (cond
		  ((stringp nextstr) (string-match nextstr name))
		  ((functionp nextstr) (funcall nextstr name))
		  (t nil))
		 (setq ignorep t
		       re-list nil)
	       (setq re-list (cdr re-list))))
	   ;; return the result
	   (if ignorep
	       (setq ido-ignored-list (cons name ido-ignored-list)))
	   ignorep)))))