Function: image-dired--create-gallery-lists

image-dired--create-gallery-lists is a byte-compiled function defined in image-dired.el.gz.

This function is obsolete since 29.1.

Signature

(image-dired--create-gallery-lists)

Documentation

Create temporary lists used by image-dired-gallery-generate.

Aliases

image-dired-create-gallery-lists (obsolete since 29.1)

Source Code

;; Defined in /usr/src/emacs/lisp/image/image-dired.el.gz
(defun image-dired--create-gallery-lists ()
  "Create temporary lists used by `image-dired-gallery-generate'."
  (declare (obsolete nil "29.1"))
  (image-dired-sane-db-file)
  (image-dired--with-db-file
    (let (end beg file row-tags)
      (setq image-dired-tag-file-list nil)
      (setq image-dired-file-tag-list nil)
      (setq image-dired-file-comment-list nil)
      (goto-char (point-min))
      (while (search-forward-regexp "^." nil t)
        (end-of-line)
        (setq end (point))
        (beginning-of-line)
        (setq beg (point))
        (unless (search-forward ";" end nil)
          (error "Something is really wrong, check format of database"))
        (setq row-tags (split-string
                        (buffer-substring beg end) ";"))
        (setq file (car row-tags))
        (dolist (x (cdr row-tags))
          (with-suppressed-warnings
              ((obsolete image-dired--add-to-tag-file-lists
                         image-dired--add-to-file-comment-list))
            (if (not (string-match "^comment:\\(.*\\)" x))
                (image-dired--add-to-tag-file-lists x file)
              (image-dired--add-to-file-comment-list file (match-string 1 x))))))))
  ;; Sort tag-file list
  (setq image-dired-tag-file-list
        (sort image-dired-tag-file-list
              (lambda (x y)
                (string< (car x) (car y))))))