Function: magit-log-refresh

magit-log-refresh is an autoloaded, interactive and byte-compiled function defined in magit-log.el.

Signature

(magit-log-refresh)

Documentation

Change the arguments used for the log(s) in the current buffer.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-log.el
;;;###autoload(autoload 'magit-log-refresh "magit-log" nil t)
(transient-define-prefix magit-log-refresh ()
  "Change the arguments used for the log(s) in the current buffer."
  :man-page "git-log"
  :class 'magit-log-refresh-prefix
  magit-log-infix-arguments
  [:if-not-mode magit-log-mode
   :description "Arguments"
   (magit-log:-n)
   (magit-log:--*-order)
   ("-g" "Show graph"               "--graph")
   ("-c" "Show graph in color"      "--color")
   ("-d" "Show refnames"            "--decorate")]
  [["Refresh"
    ("g" "buffer"                   magit-log-refresh)
    ("s" "buffer and set defaults"  transient-set-and-exit)
    ("w" "buffer and save defaults" transient-save-and-exit)]
   ["Margin"
    (magit-toggle-margin)
    (magit-cycle-margin-style)
    (magit-toggle-margin-details)
    (magit-toggle-log-margin-style)]
   [:if-mode magit-log-mode
    :description "Toggle"
    ("b" "buffer lock"              magit-toggle-buffer-lock)]]
  (interactive)
  (cond
    ((not (eq transient-current-command 'magit-log-refresh))
     (pcase major-mode
       ('magit-reflog-mode
        (user-error "Cannot change log arguments in reflog buffers"))
       ('magit-cherry-mode
        (user-error "Cannot change log arguments in cherry buffers")))
     (transient-setup 'magit-log-refresh))
    (t
     (pcase-let ((`(,args ,files) (magit-log-arguments)))
       (setq magit-buffer-log-args args)
       (unless (derived-mode-p 'magit-log-select-mode)
         (setq magit-buffer-log-files files)))
     (magit-refresh))))