Function: magit-run-section-hook

magit-run-section-hook is a byte-compiled function defined in magit-section.el.

Signature

(magit-run-section-hook HOOK &rest ARGS)

Documentation

Run HOOK with ARGS, warning about invalid entries.

Source Code

;; Defined in ~/.emacs.d/elpa/magit-section-20260330.1102/magit-section.el
(defun magit-run-section-hook (hook &rest args)
  "Run HOOK with ARGS, warning about invalid entries."
  (let ((entries (symbol-value hook)))
    (unless (listp entries)
      (setq entries (list entries)))
    (when-let ((invalid (seq-remove #'functionp entries)))
      (message "`%s' contains entries that are no longer valid.
%s\nUsing standard value instead.  Please re-configure hook variable."
               hook
               (mapconcat (##format "  `%s'" %) invalid "\n"))
      (sit-for 5)
      (setq entries (eval (car (get hook 'standard-value)))))
    (dolist (entry entries)
      (let ((magit--current-section-hook (cons (list hook entry)
                                               magit--current-section-hook)))
        (unless (memq entry magit-disabled-section-inserters)
          (if (bound-and-true-p magit-refresh-verbose)
              (let ((time (benchmark-elapse (apply entry args))))
                (message "  %-50s %f %s" entry time
                         (cond ((> time 0.03) "!!")
                               ((> time 0.01) "!")
                               (""))))
            (apply entry args)))))))