Function: magit-sequencer-process-sentinel

magit-sequencer-process-sentinel is a byte-compiled function defined in magit-process.el.

Signature

(magit-sequencer-process-sentinel PROCESS EVENT)

Documentation

Special sentinel used by magit-run-git-sequencer.

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-process.el
(defun magit-sequencer-process-sentinel (process event)
  "Special sentinel used by `magit-run-git-sequencer'."
  (when (memq (process-status process) '(exit signal))
    (magit-process-sentinel process event)
    (when-let* ((process-buf (process-buffer process))
                (_(buffer-live-p process-buf))
                (status-buf (with-current-buffer process-buf
                              (magit-get-mode-buffer 'magit-status-mode))))
      (with-current-buffer status-buf
        (when-let ((section
                    (magit-get-section
                     `((commit . ,(magit-rev-parse "HEAD"))
                       (,(pcase (car (seq-drop
                                      (process-command process)
                                      (1+ (magit-process-git-arguments--length))))
                           ((or "rebase" "am") 'rebase-sequence)
                           ((or "cherry-pick" "revert") 'sequence)))
                       (status)))))
          (goto-char (oref section start))
          (magit-section-update-highlight))))))