Function: markdown--insert-common

markdown--insert-common is a byte-compiled function defined in markdown-mode.el.

Signature

(markdown--insert-common START-DELIM END-DELIM REGEX START-GROUP END-GROUP FACE &optional SKIP-SPACE)

Source Code

;; Defined in ~/.emacs.d/elpa/markdown-mode-20260321.143/markdown-mode.el
(defun markdown--insert-common (start-delim end-delim regex start-group end-group face
                                            &optional skip-space)
  (if (use-region-p)
      ;; Active region
      (let* ((bounds (markdown-unwrap-things-in-region
                      (region-beginning) (region-end)
                      regex start-group end-group))
             (beg (car bounds))
             (end (cdr bounds)))
        (when (and beg skip-space)
          (save-excursion
            (goto-char beg)
            (skip-chars-forward " \t")
            (setq beg (point))))
        (when (and end skip-space)
          (save-excursion
            (goto-char end)
            (skip-chars-backward " \t")
            (setq end (point))))
        (markdown-wrap-or-insert start-delim end-delim nil beg end))
    (if (markdown--face-p (point) (list face))
        (save-excursion
          (while (and (markdown--face-p (point) (list face)) (not (bobp)))
            (forward-char -1))
          (forward-char (- (1- (length start-delim)))) ;; for delimiter
          (unless (bolp)
            (forward-char -1))
          (when (looking-at regex)
            (markdown-unwrap-thing-at-point nil start-group end-group)))
      (if (thing-at-point-looking-at regex)
          (markdown-unwrap-thing-at-point nil start-group end-group)
        (markdown-wrap-or-insert start-delim end-delim 'word nil nil)))))