Function: message-setup

message-setup is a byte-compiled function defined in message.el.gz.

Signature

(message-setup HEADERS &optional YANK-ACTION ACTIONS CONTINUE SWITCH-FUNCTION RETURN-ACTION)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/message.el.gz
;; YANK-ACTION, if non-nil, can be a buffer or a yank action of the
;; form (FUNCTION . ARGS).
(defun message-setup (headers &optional yank-action actions
			      continue switch-function return-action)
  (let ((mua (message-mail-user-agent))
	subject to field)
    (if (not (and message-this-is-mail mua))
	(message-setup-1 headers yank-action actions return-action)
      (setq headers (copy-sequence headers))
      (setq field (assq 'Subject headers))
      (when field
	(setq subject (cdr field))
	(setq headers (delq field headers)))
      (setq field (assq 'To headers))
      (when field
	(setq to (cdr field))
	(setq headers (delq field headers)))
      (let ((mail-user-agent mua))
	(compose-mail to subject
		      (mapcar (lambda (item)
				(cons
				 (format "%s" (car item))
				 (cdr item)))
			      headers)
		      continue switch-function
		      (if (bufferp yank-action)
			  (list 'insert-buffer yank-action)
			yank-action)
		      actions)))))