Function: nndoc-retrieve-headers

nndoc-retrieve-headers is a byte-compiled function defined in nndoc.el.gz.

Signature

(nndoc-retrieve-headers ARTICLES &optional NEWSGROUP SERVER FETCH-OLD)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nndoc.el.gz
(deffoo nndoc-retrieve-headers (articles &optional newsgroup server _fetch-old)
  (when (nndoc-possibly-change-buffer newsgroup server)
    (with-current-buffer nntp-server-buffer
      (erase-buffer)
      (let (article entry)
	(if (stringp (car articles))
	    'headers
	  (while articles
	    (when (setq entry (cdr (assq (setq article (pop articles))
					 nndoc-dissection-alist)))
	      (let ((start (point)))
		(insert (format "221 %d Article retrieved.\n" article))
		(if nndoc-generate-head-function
		    (funcall nndoc-generate-head-function article)
		  (insert-buffer-substring
		   nndoc-current-buffer (car entry) (nth 1 entry)))
		(goto-char (point-max))
		(unless (eq (char-after (1- (point))) ?\n)
		  (insert "\n"))
		(insert (format "Lines: %d\n" (nth 4 entry)))
		(insert ".\n")
		(when nndoc-header-transform-function
		  (save-excursion
		    (save-restriction
		      (narrow-to-region start (point))
		      (funcall nndoc-header-transform-function entry)))))))
	  (nnheader-fold-continuation-lines)
	  'headers)))))