Function: nnfolder-request-move-article

nnfolder-request-move-article is a byte-compiled function defined in nnfolder.el.gz.

Signature

(nnfolder-request-move-article ARTICLE GROUP SERVER ACCEPT-FORM &optional LAST MOVE-IS-INTERNAL)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnfolder.el.gz
(deffoo nnfolder-request-move-article (article group server accept-form
					       &optional last _move-is-internal)
  (save-excursion
    (let ((buf (gnus-get-buffer-create " *nnfolder move*"))
	  result)
      (and
       (nnfolder-request-article article group server)
       (with-current-buffer buf
	 (erase-buffer)
	 (insert-buffer-substring nntp-server-buffer)
	 (goto-char (point-min))
	 (while (re-search-forward
		 (concat "^" nnfolder-article-marker)
		 (save-excursion (and (search-forward "\n\n" nil t) (point)))
		 t)
	   (gnus-delete-line))
	 (setq result (eval accept-form t))
	 (kill-buffer buf)
	 result)
       (save-excursion
	 (nnfolder-possibly-change-group group server)
	 (set-buffer nnfolder-current-buffer)
	 (goto-char (point-min))
	 (when (nnfolder-goto-article article)
	   (nnfolder-delete-mail))
	 (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
	   (nnfolder-nov-delete-article group article))
	 (when last
	   (nnfolder-save-buffer)
	   (nnfolder-adjust-min-active group)
	   (nnfolder-save-active nnfolder-group-alist nnfolder-active-file))))
      result)))