Function: nnmbox-request-article

nnmbox-request-article is a byte-compiled function defined in nnmbox.el.gz.

Signature

(nnmbox-request-article ARTICLE &optional NEWSGROUP SERVER BUFFER)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmbox.el.gz
(deffoo nnmbox-request-article (article &optional newsgroup server buffer)
  (nnmbox-possibly-change-newsgroup newsgroup server)
  (with-current-buffer nnmbox-mbox-buffer
    (save-excursion
      (when (nnmbox-find-article article)
        (let (start stop)
          (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
          (setq start (point))
          (forward-line 1)
          (setq stop (if (re-search-forward (concat "^"
                                                    message-unix-mail-delimiter)
                                            nil 'move)
                         (match-beginning 0)
                       (point)))
          (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
            (set-buffer nntp-server-buffer)
            (erase-buffer)
            (insert-buffer-substring nnmbox-mbox-buffer start stop)
            (goto-char (point-min))
            (while (looking-at "From ")
              (delete-char 5)
              (insert "X-From-Line: ")
              (forward-line 1))
            (if (numberp article)
                (cons nnmbox-current-group article)
              (nnmbox-article-group-number nil))))))))