Function: nnspool-request-newgroups

nnspool-request-newgroups is a byte-compiled function defined in nnspool.el.gz.

Signature

(nnspool-request-newgroups DATE &optional SERVER)

Documentation

List groups created after DATE.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnspool.el.gz
;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
(deffoo nnspool-request-newgroups (date &optional _server)
  "List groups created after DATE."
  (if (nnspool-find-file nnspool-active-times-file)
      (save-excursion
	;; Find the last valid line.
	(goto-char (point-max))
	(while (and (not (looking-at
			  "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
		    (zerop (forward-line -1))))
	(let ((seconds (time-convert (date-to-time date) 'integer))
	      groups)
	  ;; Go through lines and add the latest groups to a list.
	  (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
		      (progn
			(goto-char (match-end 1))
			(< seconds (read (current-buffer))))
		      (progn
			(push (buffer-substring
			       (match-beginning 1) (match-end 1))
			      groups)
			(zerop (forward-line -1)))))
	  (erase-buffer)
	  (dolist (group groups)
	    (insert group " 0 0 y\n")))
	t)
    nil))