Function: org--batch-store-agenda-views

org--batch-store-agenda-views is a byte-compiled function defined in org-agenda.el.gz.

Signature

(org--batch-store-agenda-views VARS VALS)

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-agenda.el.gz
(defun org--batch-store-agenda-views (vars vals)
  (let ((cmds (org-agenda-normalize-custom-commands org-agenda-custom-commands))
        (pop-up-frames nil)
        (dir default-directory)
        cmd thiscmdkey thiscmdcmd match files opts cmd-or-set bufname)
    (save-window-excursion
      (while cmds
	(setq cmd (pop cmds)
	      thiscmdkey (car cmd)
	      thiscmdcmd (cdr cmd)
	      match (nth 2 thiscmdcmd)
	      bufname (if org-agenda-sticky
			  (or (and (stringp match)
				   (format "*Org Agenda(%s:%s)*" thiscmdkey match))
			      (format "*Org Agenda(%s)*" thiscmdkey))
			org-agenda-buffer-name)
	      cmd-or-set (nth 2 cmd)
	      opts (nth (if (listp cmd-or-set) 3 4) cmd)
	      files (nth (if (listp cmd-or-set) 4 5) cmd))
	(if (stringp files) (setq files (list files)))
	(when files
	  (let* ((opts (append org-agenda-exporter-settings opts))
                 (vars (append (mapcar #'car opts) vars))
                 (vals (append (mapcar (lambda (binding) (eval (cadr binding) t))
                                       opts)
                               vals)))
	    (cl-progv vars vals
	      (org-agenda nil thiscmdkey))
	    (set-buffer bufname)
	    (while files
	      (cl-progv vars vals
                (org-agenda-write (expand-file-name (pop files) dir)
                                  nil t bufname))))
	  (and (get-buffer bufname)
	       (kill-buffer bufname)))))))